# Maintainer: Johannes Schindelin/Matthew J Cheetham

_realname="git-credential-manager"
pkgbase="mingw-w64-${_realname}"
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
conflicts=("${MINGW_PACKAGE_PREFIX}-git-credential-manager-core")
replaces=("${MINGW_PACKAGE_PREFIX}-git-credential-manager-core")
pkgver=2.9.1
pkgrel=1
_realver=$pkgver
_realtag=v${pkgver}
pkgdesc="Credential Manager for Git"
install=git-credential-manager.install
arch=('any')
project_url="https://github.com/git-ecosystem/git-credential-manager"
license=('MIT')
makedepends=('markdown'
             'unzip')
groups=('VCS')
options=('!strip')

case "$CARCH" in
  i686)
    _arch=x86
    _sha=076d120618e876f06cf47cdb79aabda2d4afe89701a2b4e81f441d8b20200d35
    ;;
  x86_64)
    _arch=x64
    _sha=7dea2afd3b9ea22109d25f95066025d70e57281d96062605304f89fcca41b535
    ;;
  aarch64)
    _arch=arm64
    _sha=1b573743a6162415d8398cbd9e2201aa8c43fd291bf45c242a5a12fa5ded3bd1
    ;;
  *)
    _arch=x86
    _sha=076d120618e876f06cf47cdb79aabda2d4afe89701a2b4e81f441d8b20200d35
    ;;
esac

zip_name="gcm-win-${_arch}-${_realver}.zip"
zip_url="${project_url}/releases/download/${_realtag}/${zip_name}"
src_zip_url="${project_url}/archive/${_realtag}.zip"

source=("${zip_url}" "$src_zip_url")
noextract=("${zip_name}")

sha256sums=("$_sha"
            '9840032828f0e489277244a1e9dfc9db141dad4f6be692fb31ba46d8058ddf53')

build() {
  markdown "${srcdir}/git-credential-manager-${_realtag#v}/README.md" > "${srcdir}/git-credential-manager-${_realtag#v}/git-credential-manager.html"
}

prepare() {
  mkdir -p "${srcdir}/${MINGW_PACKAGE_PREFIX#mingw-w64-}"
  unzip "${srcdir}/${zip_name}" -d "${srcdir}/${MINGW_PACKAGE_PREFIX#mingw-w64-}"
}

package() {
  prefix="$pkgdir/${MINGW_PREFIX}"
  bindir="${srcdir}/${MINGW_PACKAGE_PREFIX#mingw-w64-}"
  install -d -m755 "${prefix}"/bin
  install -m755 "$bindir"/*.{dll,exe,config} "${prefix}"/bin
  install -d -m755 "${prefix}"/doc/git-credential-manager
  install -m644 "$srcdir"/git-credential-manager-${_realtag#v}/{README.md,LICENSE,NOTICE} "${prefix}"/doc/git-credential-manager
  install -d -m755 "${prefix}"/share/doc/git-doc
  install -m644 "$srcdir"/git-credential-manager-${_realtag#v}/git-credential-manager.html "${prefix}"/share/doc/git-doc
}
