# Maintainer: Masanori Shirayama <mashir43@gmail.com>

pkgname=mksh
_ver=56c
# use a pacman compatible version scheme
pkgver=${_ver/[a-z]/.${_ver//[0-9.]/}}
pkgrel=1
pkgdesc="The MirBSD Korn Shell"
arch=("i686" "x86_64")
url="https://www.mirbsd.org/mksh.htm"
license=('ISC')
depends=('gcc-libs')
makedepends=('gcc')
provides=('ksh')
conflicts=('ksh')
install=mksh.install
source=("http://www.mirbsd.org/MirOS/dist/mir/${pkgname}/${pkgname}-R${_ver}.tgz"
        "http://www.mirbsd.org/TaC-mksh.txt")
sha256sums=('dd86ebc421215a7b44095dc13b056921ba81e61b9f6f4cdab08ca135d02afb77'
            '226531c00889d4d16ff06335d0405458ca13baa525a1379e384da33527707a55')

build() {
  cd "${srcdir}/${pkgname}"

  ./Build.sh
}

check() {
  cd "${srcdir}/${pkgname}"
  ./test.sh
}

package() {
  cd "${srcdir}/${pkgname}"

  mkdir -p "${pkgdir}/usr/bin"
  mkdir -p "${pkgdir}/usr/share/man/man1"
  mkdir -p "${pkgdir}/usr/share/licenses/mksh"

  cp -f mksh.exe ${pkgdir}/usr/bin
  cp -f mksh.1 ${pkgdir}/usr/share/man/man1

  cd "${srcdir}"
  cp -f TaC-mksh.txt ${pkgdir}/usr/share/licenses/mksh

  cd "${pkgdir}/usr/bin"
  cp -f mksh.exe ksh.exe
}
